.include "can128def.inc"

#define temp_max 41
#define temp_min 5
#define percent_low 2
#define rept_cnt 20

;mappings for 16 MHz CPU clock
;taken from AT90CANLIB
; 125Kb/s, 16x Tscl, sampling at 75%
#       define CONF_CANBT1  0x0E       // Tscl  = 8x Tclkio = 500 ns
#       define CONF_CANBT2  0x0C       // Tsync = 1x Tscl, Tprs = 7x Tscl, Tsjw = 1x Tscl
#       define CONF_CANBT3  0x37       // Tpsh1 = 4x Tscl, Tpsh2 = 4x Tscl, 3 sample points


#define LCD_RW PORTG,0
#define LCD_RS PORTG,1
#define LCD_E  PORTG,2
#define LCD_DATA_OUT PORTC
#define LCD_DATA_IN PINC
#define LCD_DATA_DDR DDRC

#define SRC_RAM GPIOR0,0

.macro can_msg8
	.db @0,$ff & @1<<5,$ff & @1>>3,8,@2,@3,@4,@5,@6,@7,@8,@9,@10        ,-1
.endm

	rjmp start

	.org CANITaddr
	rjmp can_int

start:
	ldi r16,HIGH(RAMEND)
	out SPL,r16
	ldi r16,HIGH(RAMEND)
	out SPH,r16

	ldi r16,1<<SE	;enable idle mode
	out SMCR,r16

	clr r16
	sts (temp_cnt),r16
	sts (percent_cnt),r16

	clr r16
	out LCD_DATA_DDR,r16
	ldi r16,-1
	out LCD_DATA_OUT,r16

	cbi LCD_E
	cbi LCD_RS
	sbi LCD_RW
	ldi r16,7
	out DDRG,r16

	rcall display_init_str

	ldi ZL,LOW(lcd_init_str*2)
	ldi ZH,HIGH(lcd_init_str*2)
	cbi SRC_RAM
	rcall lcd_cmd_str

	rcall display_set

	clr r16
	sts (can_buf_wr_ptr),r16
	sts (can_buf_rd_ptr),r16

	ldi r16,1<<SWRES
	sts (CANGCON),r16
	ldi r16,CONF_CANBT1
	sts (CANBT1),r16
	ldi r16,CONF_CANBT2
	sts (CANBT2),r16
	ldi r16,CONF_CANBT3
	sts (CANBT3),r16

;clear all MOBs
	ldi r16,0
	clr r0
clr_mob_lp:
	sts (CANPAGE),r16
	sts (CANSTMOB),r0
	sts (CANSTML),r0
	subi r16,-$10
	cpi r16,$f0
	brne clr_mob_lp

;set up MOB 14 to receive any CAN message
	ldi r16,$e0
	sts (CANPAGE),r16
	ldi r17,8
	clr r16
fill_buf:
	sts (CANMSG),r16
	dec r17
	brne fill_buf
	sts (CANIDT4),r16
	sts (CANIDT3),r16
	sts (CANIDT2),r16
	sts (CANIDT1),r16
	sts (CANIDM4),r16
	sts (CANIDM3),r16
	sts (CANIDM2),r16
	sts (CANIDM1),r16

	ldi r16,1<<CONMOB1	;receive message
	sts (CANCDMOB),r16

	ldi r16,1<<IEMOB14
	sts (CANIE1),r16
	ldi r16,1<<ENIT|1<<ENRX
	sts (CANGIE),r16
	ldi r16,1<<ENASTB
	sts (CANGCON),r16

	sei

msg_loop:
	sleep
chk_msg:
	lds YL,(can_buf_rd_ptr)
	lds r16,(can_buf_wr_ptr)
	cp YL,r16
	breq msg_loop
	ldi YH,HIGH(can_rcv_buf)
	ld r16,Y
	inc YL
	ld r17,Y
	inc YL
	ld r18,Y
	inc YL
	tst r17
	breq hndl_msg
hndl_msg_x:
	add YL,r18
	sts (can_buf_rd_ptr),YL
	rjmp chk_msg
hndl_msg:
	cpi r16,$31
	brne hndl_msg1
	ld r16,Y
	cpi r16,2
	brne hndl_msg_x
	ldi ZL,LOW(can_msg_confirm_sw_off*2)
	ldi ZH,HIGH(can_msg_confirm_sw_off*2)
	rcall can_send_msg
	rcall display_init_str
	rcall display_set
	rjmp hndl_msg_x
hndl_msg1:
	cpi r16,$30
	brne hndl_msg_x
	push YL
	subi YL,-3
	ld r16,Y
	cpi r16,temp_max
	brge temp_oorange
	cpi r16,temp_min
	brlt temp_oorange
	inc YL
	ld r16,Y
	cpi r16,percent_low
	brge hndl_msg1a
	lds r16,(percent_cnt)
	cpi r16,rept_cnt
	brcc shutdown
	inc r16
	sts (percent_cnt),r16
	rjmp hndl_msg1b
temp_oorange:
	lds r16,(temp_cnt)
	cpi r16,rept_cnt
	brcc shutdown
	inc r16
	sts (temp_cnt),r16
	rjmp hndl_msg1b
shutdown:
	ldi ZL,LOW(can_msg_request_shutdown*2)
	ldi ZH,HIGH(can_msg_request_shutdown*2)
	clr r16
	sts (temp_cnt),r16
	sts (percent_cnt),r16
	rjmp hndl_msg1c
hndl_msg1a:
	clr r16
	sts (temp_cnt),r16
	sts (percent_cnt),r16
hndl_msg1b:
	ldi ZL,LOW(can_msg_alive*2)
	ldi ZH,HIGH(can_msg_alive*2)
hndl_msg1c:
	rcall can_send_msg
	pop YL
	push YL
	push r18
	rcall show_batt_state
	pop r18
	pop YL
	rjmp hndl_msg_x


show_batt_state:
	subi YL,-2
	ld r16,Y
	inc YL
	ldi XL,LOW(display_volt)
	ldi XH,HIGH(display_volt)
	rcall bin2bcd
	ld r16,Y
	inc YL
	tst r16
	brpl degree_pos
	ldi r16,0
degree_pos:
	ldi XL,LOW(display_degree)
	ldi XH,HIGH(display_degree)
	rcall bin2bcd
	ld r16,Y
	inc YL
	ldi XL,LOW(display_percent)
	ldi XH,HIGH(display_percent)
	rcall bin2bcd
	ld r17,Y
	ldi XL,LOW(display_bar)
	ldi XH,HIGH(display_bar)
	ldi r18,0
	ldi r16,1
bar_lp:
	cp r18,r17
	brne bar1
	ldi r16,2
bar1:
	st X+,r16
	inc r18
	cpi r18,5
	brne bar_lp
	rcall display_set
	ret

display_set:
	ldi ZL,LOW(display_str)
	ldi ZH,HIGH(display_str)
	sbi SRC_RAM
lcd_cmd_str:
	sbis SRC_RAM
	lpm r17,Z+
	sbic SRC_RAM
	ld r17,Z+
	tst r17
	breq lcd_cmd_str_x
	brmi lcd_data_str
lcd_cmd_str_lp:
	sbis SRC_RAM
	lpm r16,Z+
	sbic SRC_RAM
	ld r16,Z+
	rcall lcd_command
	dec r17
	brne lcd_cmd_str_lp
	rjmp lcd_cmd_str
lcd_data_str:
	andi r17,$7f
lcd_data_str_lp:
	sbis SRC_RAM
	lpm r16,Z+
	sbic SRC_RAM
	ld r16,Z+
	rcall lcd_data
	dec r17
	brne lcd_data_str_lp
	rjmp lcd_cmd_str
lcd_cmd_str_x:
	ret

lcd_data:
	push r16
	rcall lcd_chk_busy
	sbi LCD_RS
	rjmp lcd_common

lcd_command:
	push r16
	rcall lcd_chk_busy
lcd_common:
	cbi LCD_RW
	ldi r16,-1
	out LCD_DATA_DDR,r16
	pop r16
	out LCD_DATA_OUT,r16
	sbi LCD_E
	rcall lcd_delay
	cbi LCD_E
	clr r16                                                                                                                                    
	out LCD_DATA_DDR,r16
	ret

lcd_chk_busy:
	cbi LCD_RS
	sbi LCD_RW
lcd_chk_busy_lp:
	sbi LCD_E
	rcall lcd_delay
	in r16,LCD_DATA_IN
	cbi LCD_E
	sbrs r16,7
	ret
	rcall lcd_delay
	rjmp lcd_chk_busy_lp

lcd_delay:
	ldi r16,3
lcd_delay_lp:
	dec r16
	brne lcd_delay_lp
	ret	

display_init_str:
	ldi ZL,LOW(display_template*2)
	ldi ZH,HIGH(display_template*2)
	ldi XL,LOW(display_str)
	ldi XH,HIGH(display_str)
	ldi r17,(display_template_x-display_template)*2
copy_disp_str_lp:
	lpm r16,Z+
	st X+,r16
	dec r17
	brne copy_disp_str_lp
	ret

can_send_msg:
	lpm r16,Z+
	sts (CANPAGE),r16
	ldi r16,0
	sts (CANIDT4),r16
	sts (CANIDT3),r16
	sts (CANIDM4),r16
	sts (CANIDM3),r16
	lpm r16,Z+
	sts (CANIDT2),r16
	lpm r16,Z+
	sts (CANIDT1),r16
	ldi r16,7<<5
	sts (CANIDM2),r16
	ldi r16,-1
	sts (CANIDM1),r16
	lpm r17,Z+
can_int_fill_lp:
	lpm r16,Z+
	sts (CANMSG),r16
	dec r17
	brne can_int_fill_lp
	lpm r16,Z
	sts (CANCDMOB),r16
	ret

can_int:
	push r16
	in r16,sreg
	push r16
	push r17
	push YL
	push YH
	lds r16,(CANGIT)
	sts (CANGIT),r16
	lds r16,(CANSIT1)
	sbrs r16,SIT14
	rjmp can_intx
	ldi r16,$e0
	sts (CANPAGE),r16
	lds r16,(CANIDT1)
	lds r17,(CANIDT2)
	lsr r16
	ror r17
	lsr r16
	ror r17
	lsr r16
	ror r17
	lsr r16
	ror r17
	lsr r16
	ror r17
	lds YL,(can_buf_wr_ptr)
	ldi YH,HIGH(can_rcv_buf)
	st Y,r17
	inc YL
	st Y,r16
	inc YL
	lds r17,(CANCDMOB)
	andi r17,15
	st Y,r17
	inc YL
can_int_fetch_msg:
	lds r16,(CANMSG)
	st Y,r16
	inc YL
	dec r17
	brne can_int_fetch_msg
	sts (can_buf_wr_ptr),YL
can_intx:
	ldi r16,$e0
	sts (CANPAGE),r16
	ldi r16,0
	sts (CANSTMOB),r16
	sts (CANIDT4),r16
	sts (CANIDT3),r16
	sts (CANIDT2),r16
	sts (CANIDT1),r16
	ldi r16,1<<CONMOB1	;receive message
	sts (CANCDMOB),r16
	pop YH
	pop YL
	pop r17
	pop r16
	out sreg,r16
	pop r16
	reti

bin2bcd:
	ldi r17,8
	clr r18
	clr r19
bin2bcd_lp:
	lsl r16
	rol r18
	rol r19
	dec r17
	breq bin2bcd_x
	subi r18,-$33
	sbrs r18,3
	subi r18,3
	sbrs r18,7
	subi r18,$30
	rjmp bin2bcd_lp
bin2bcd_x:
	clt
	mov r16,r19
	rcall digit
	mov r16,r18
	swap r16
	rcall digit
	mov r16,r18
	set
digit:
	andi r16,15
	brne digit1
	brts digit1
	ldi r16,' '
	rjmp digit_set
digit1:
	set
	subi r16,-'0'
digit_set:
	st X+,r16
	ret

display_template:
 .db 1,0b10000000,16+$80,"--- Volt  -- ",$df,"C ",1,0b11000000,16+$80,"---%      ",2,2,2,2,2," ",0,-1
display_template_x:

lcd_init_str:
 .db 5,0b00111100,0b00001100,0b00000001,0b00000110,0b01001000
 .db 16+$80,0b00011111,0b00011111,0b00011111,0b00011111,0b00011111,0b00011111,0b00011111,0b00000000,0b00010101,0b00000000,0b00010001,0b00000000,0b00010001,0b00000000,0b00010101,0b00000000,0

can_msg_alive:
 can_msg8 $d0,$23,4,0,0,0,0,0,0,0,1<<CONMOB0|8
can_msg_confirm_sw_off:
 can_msg8 $d0,$23,8,0,0,0,0,0,0,0,1<<CONMOB0|8
can_msg_request_shutdown:
 can_msg8 $d0,$23,2,0,0,0,0,0,0,0,1<<CONMOB0|8

 .dseg
 .org SRAM_START

can_rcv_buf:
 .byte 256
can_buf_wr_ptr:
 .byte 1
can_buf_rd_ptr:
 .byte 1
temp_cnt:
 .byte 1
percent_cnt:
 .byte 1
display_str:
 .byte 3+16+3+16+1
 .equ display_volt=display_str+3
 .equ display_degree=display_str+12
 .equ display_percent=display_str+22
 .equ display_bar=display_str+32